excel表格常用函数技巧大全|excel函数公式大全及使用方法

excel表格常用函数技巧大全|excel函数公式大全及使用方法）

在会计同事电脑中，保保经常看到海量的Excel表格，员工基本信息、提成计算、考勤统计、合同管理....看来再完备的会计系统也取代不了Excel表格的作用。于是，保保尽可能多的收集会计工作中的Excel公式，所以就有了这篇本平台史上最全HR的Excel公式+数据分析技巧集。

一、员工信息表公式

1、计算性别(F列)

=IF(MOD(MID(E3,17,1),2),"男","女")

2、出生年月(G列)

=TEXT(MID(E3,7,8),"0-00-00")

3、年龄公式(H列)

=DATEDIF(G3,TODAY(),"y")

4、退休日期(I列)

=TEXT(EDATE(G3,12*(5*(F3="男")+55)),"yyyy/mm/dd aaaa")

5、籍贯(M列)

=VLOOKUP(LEFT(E3,6)*1,地址库!E:F,2,)

注:附带示例中有地址库代码表

6、社会工龄(T列)

=DATEDIF(S3,NOW(),"y")

7、公司工龄(W列)

=DATEDIF(V3,NOW(),"y")&"年"&DATEDIF(V3,NOW(),"ym")&"月"&DATEDIF(V3,NOW(),"md")&"天"

8、合同续签日期(Y列)

=DATE(YEAR(V3)+LEFTB(X3,2),MONTH(V3),DAY(V3))-1

9、合同到期日期(Z列)

=TEXT(EDATE(V3,LEFTB(X3,2)*12)-TODAY(),"[

10、工龄工资(AA列)

=MIN(700,DATEDIF($V3,NOW(),"y")*50)

11、生肖(AB列)

=MID("猴鸡狗猪鼠牛虎兔龙蛇马羊",MOD(MID(E3,7,4),12)+1,1)

二、员工考勤表公式

1、本月工作日天数(AG列)

=NETWORKDAYS(B$5,DATE(YEAR(N$4),MONTH(N$4)+1,),)

2、调休天数公式(AI列)

=COUNTIF(B9:AE9,"调")

3、扣钱公式(AO列)

婚丧扣10块，病假扣20元，事假扣30元，矿工扣50元

=SUM((B9:AE9={"事";"旷";"病";"丧";"婚"})*{30;50;20;10;10})

四、员工数据分析公式

1、本科学历人数

=COUNTIF(D:D,"本科")

2、办公室本科学历人数

=COUNTIFS(A:A,"办公室",D:D,"本科")

3、30~40岁总人数

=COUNTIFS(F:F,">=30",F:F,"

五、其他公式

1、提成比率计算

=VLOOKUP(B3,$C$12:$E$21,3)

2、个人所得税计算

假如A2中是应税工资，则计算个税公式为:

=5*MAX(A2*{0.6,2,4,5,6,7,9}%-{21,91,251,376,761,1346,3016},)

3、工资条公式

=CHOOSE(MOD(ROW(A3),3)+1,工资数据源!A$1,OFFSET(工资数据源!A$1,INT(ROW(A3)/3),,),"")

注:

A3:标题行的行数+2,如果标题行在第3行，则A3改为A5 工资数据源!A$1:工资表的标题行的第一列位置

4、Countif函数统计身份证号码出错的解决方法

由于Excel中数字只能识别15位内的，在Countif统计时也只会统计前15位，所以很容易出错。不过只需要用&"*"转换为文本型即可正确统计。

=Countif(A:A,A2&"*")

六、利用数据透视表完成数据分析

1、各部门人数占比

统计每个部门占总人数的百分比

2、各个年龄段人数和占比

公司员工各个年龄段的人数和占比各是多少呢?

3、各个部门各年龄段占比

分部门统计本部门各个年龄段的占比情况

4、各部门学历统计

各部门大专、本科、硕士和博士各有多少人呢?

5、按年份统计各部门入职人数

每年各部门入职人数情况

一、Excel基本公式

1、查找重复内容公式：=IF(COUNTIF(A:A,A2)>1,"重复","")。

2、用出生年月来计算年龄公式：=TRUNC((DAYS360(H6,"2009/8/30",FALSE))/360,0)。

3、从输入的18位身份证号的出生年月计算公式：=CONCATENATE(MID(E2,7,4),"/",MID(E2,11,2),"/",MID(E2,13,2))。

4、从输入的身份证号码内让系统自动提取性别，可以输入以下公式：

=IF(LEN(C2)=15,IF(MOD(MID(C2,15,1),2)=1,"男","女"),IF(MOD(MID(C2,17,1),2)=1,"男","女"))公式内的“C2”代表的是输入身份证号码的单元格。

1、求和： =SUM(K2:K56) ——对K2到K56这一区域进行求和;

2、平均数： =AVERAGE(K2:K56) ——对K2 K56这一区域求平均数;

3、排名： =RANK(K2，K$2:K$56) ——对55名学生的成绩进行排名;

4、等级： =IF(K2>=85,"优",IF(K2>=74,"良",IF(K2>=60,"及格","不及格")))

5、学期总评： =K2*0.3+M2*0.3+N2*0.4 ——假设K列、M列和N列分别存放着学生的“平时总评”、“期中”、“期末”三项成绩;

6、最高分： =MAX(K2:K56) ——求K2到K56区域(55名学生)的最高分;

7、最低分： =MIN(K2:K56) ——求K2到K56区域(55名学生)的最低分;

8、分数段人数统计：

(1) =COUNTIF(K2:K56,"100") ——求K2到K56区域100分的人数;假设把结果存放于K57单元格;

(2) =COUNTIF(K2:K56,">=95")-K57 ——求K2到K56区域95～99.5分的人数;假设把结果存放于K58单元格;

(3)=COUNTIF(K2:K56,">=90")-SUM(K57:K58) ——求K2到K56区域90～94.5分的人数;假设把结果存放于K59单元格;

(4)=COUNTIF(K2:K56,">=85")-SUM(K57:K59) ——求K2到K56区域85～89.5分的人数;假设把结果存放于K60单元格;

(5)=COUNTIF(K2:K56,">=70")-SUM(K57:K60) ——求K2到K56区域70～84.5分的人数;假设把结果存放于K61单元格;

(6)=COUNTIF(K2:K56,">=60")-SUM(K57:K61) ——求K2到K56区域60～69.5分的人数;假设把结果存放于K62单元格;

(7) =COUNTIF(K2:K56,"<60") ——求K2到K56区域60分以下的人数;假设把结果存放于K63单元格;

说明：COUNTIF函数也可计算某一区域男、女生人数。

如：=COUNTIF(C2:C351,"男") ——求C2到C351区域(共350人)男性人数;

9、优秀率： =SUM(K57:K60)/55*100

10、及格率： =SUM(K57:K62)/55*100

11、标准差： =STDEV(K2:K56) ——求K2到K56区域(55人)的成绩波动情况(数值越小，说明该班学生间的成绩差异较小，反之，说明该班存在两极分化);

12、条件求和： =SUMIF(B2:B56,"男"，K2:K56) ——假设B列存放学生的性别，K列存放学生的分数，则此函数返回的结果表示求该班男生的成绩之和;

13、多条件求和： {=SUM(IF(C3:C322="男",IF(G3:G322=1,1,0)))｝ ——假设C列(C3:C322区域)存放学生的性别，G列(G3:G322区域)存放学生所在班级代码(1、2、3、4、5)，则此函数返回的结果表示求一班的男生人数;这是一个数组函数，输完后要按Ctrl+Shift+Enter组合键(产生“{……｝”)。“{｝”不能手工输入，只能用组合键产生。

14、根据出生日期自动计算周岁：=TRUNC((DAYS360(D3,NOW( )))/360,0)

———假设D列存放学生的出生日期，E列输入该函数后则产生该生的周岁。

15、在Word中三个小窍门：

①连续输入三个“~”可得一条波浪线。

②连续输入三个“-”可得一条直线。

连续输入三个“=”可得一条双直线。

一、excel中当某一单元格符合特定条件，如何在另一单元格显示特定的颜色比如：

A1〉1时，C1显示红色

A1<0时，C1显示黄色

方法如下：

1、单元击C1单元格，点“格式”>“条件格式”，条件1设为：

公式 =A1=1

2、点“格式”->“字体”->“颜色”，点击红色后点“确定”。

条件2设为：

公式 =AND(A1>0,A1<1)

3、点“格式”->“字体”->“颜色”，点击绿色后点“确定”。

条件3设为：

公式 =A1<0

点“格式”->“字体”->“颜色”，点击黄色后点“确定”。

4、三个条件设定好后，点“确定”即出。

二、EXCEL中如何控制每列数据的长度并避免重复录入

1、用数据有效性定义数据长度。

用鼠标选定你要输入的数据范围，点"数据"->"有效性"->"设置"，"有效性条件"设成"允许""文本长度""等于""5"(具体条件可根据你的需要改变)。

还可以定义一些提示信息、出错警告信息和是否打开中文输入法等，定义好后点"确定"。

2、用条件格式避免重复。

选定A列，点"格式"->"条件格式"，将条件设成“公式=COUNTIF($A:$A,$A1)>1”，点"格式"->"字体"->"颜色"，选定红色后点两次"确定"。

这样设定好后你输入数据如果长度不对会有提示，如果数据重复字体将会变成红色。

三、在EXCEL中如何把B列与A列不同之处标识出来?

(一)、如果是要求A、B两列的同一行数据相比较：

假定第一行为表头，单击A2单元格，点“格式”->“条件格式”，将条件设为:

“单元格数值” “不等于”=B2

点“格式”->“字体”->“颜色”，选中红色，点两次“确定”。

用格式刷将A2单元格的条件格式向下复制。

B列可参照此方法设置。

(二)、如果是A列与B列整体比较(即相同数据不在同一行)：

假定第一行为表头，单击A2单元格，点“格式”->“条件格式”，将条件设为:

“公式”=COUNTIF($B:$B,$A2)=0

点“格式”->“字体”->“颜色”，选中红色，点两次“确定”。

用格式刷将A2单元格的条件格式向下复制。

B列可参照此方法设置。

按以上方法设置后，AB列均有的数据不着色，A列有B列无或者B列有A列无的数据标记为红色字体。

四、EXCEL中怎样批量地处理按行排序

假定有大量的数据(数值)，需要将每一行按从大到小排序，如何操作?

由于按行排序与按列排序都是只能有一个主关键字,主关键字相同时才能按次关键字排序。所以，这一问题不能用排序来解决。解决方法如下：

1、假定你的数据在A至E列，请在F1单元格输入公式：

=LARGE($A1:$E1,COLUMN(A1))

用填充柄将公式向右向下复制到相应范围。

你原有数据将按行从大到小排序出现在F至J列。如有需要可用“选择性粘贴/数值”复制到其他地方。

注：第1步的公式可根据你的实际情况(数据范围)作相应的修改。如果要从小到大排序,公式改为:=SMALL($A1:$E1,COLUMN(A1))

五、巧用函数组合进行多条件的计数统计

例：第一行为表头，A列是“姓名”，B列是“班级”，C列是“语文成绩”，D列是“录取结果”，现在要统计“班级”为“二”，“语文成绩”大于等于104，“录取结果”为“重本”的人数。统计结果存放在本工作表的其他列。

公式如下：

=SUM(IF((B2:B9999="二")*(C2:C9999>=104)*(D2:D9999="重本"),1,0))

输入完公式后按Ctrl+Shift+Enter键,让它自动加上数组公式符号"{}"。

六、如何判断单元格里是否包含指定文本?

假定对A1单元格进行判断有无"指定文本",以下任一公式均可:

=IF(COUNTIF(A1,"*"&"指定文本"&"*")=1,"有","无")

=IF(ISERROR(FIND("指定文本",A1,1)),"无","有")

求某一区域内不重复的数据个数

例如求A1:A100范围内不重复数据的个数，某个数重复多次出现只算一个。有两种计算方法：

一是利用数组公式：

=SUM(1/COUNTIF(A1:A100,A1:A100))

输入完公式后按Ctrl+Shift+Enter键,让它自动加上数组公式符号"{}"。

二是利用乘积求和函数：

=SUMPRODUCT(1/COUNTIF(A1:A100,A1:A100))

七、一个工作薄中有许多工作表如何快速整理出一个目录工作表

1、用宏3.0取出各工作表的名称，方法：

Ctrl+F3出现自定义名称对话框，取名为X，在“引用位置”框中输入：

=MID(GET.WORKBOOK(1),FIND("]",GET.WORKBOOK(1))+1,100)

确定

2、用HYPERLINK函数批量插入连接，方法：

在目录工作表(一般为第一个sheet)的A2单元格输入公式：

=HYPERLINK("#'"&INDEX(X,ROW())&"'!A1",INDEX(X,ROW()))

将公式向下填充，直到出错为止，目录就生成了。